SIRALI – SEQUENCE Fonksiyonu

Excel SIRALI – SEQUENCE Fonksiyonu Kullanımı

Excel SIRALI – SEQUENCE fonksiyonu, bir dizi içinde ardışık sayıların listesini oluşturmaktadır. Böylece, dizi satır ve sütun argümanlarıyla belirlenen tek boyutlu veya iki boyutlu olacaktır. Ayrıca bu fonksiyon, Excel Destek içinde oldukça önemli bir fonksiyondur ve çok fazla formül örneği olarak kullanılmaktadır.

Amacı

Ardışık sayıların listesini içeren bir dizi almayı sağlamaktır.

Dönen Değer

Ardışık değerlerden bir dizi oluşturmak.

Söz Dizimi

=SIRALI(satırlar; [sütunlar]; [başlangıç]; [artış])

• satırlar: Döndürülen satır sayısı.
• sütunlar: (İsteğe bağlı) Döndürülen sütun sayısı.
• başlangıç: (İsteğe bağlı) Başlangıç değeri (varsayılan 1’dir).
• artış: (İsteğe bağlı) Her değer arasındaki artış (varsayılan 1’dir).

Nasıl Kullanılmaktadır

SIRALI fonksiyonu, bir dizi içinde ardışık sayıların listesini oluşturmaktadır. Böylece, dizi satır ve sütun argümanlarıyla belirlenen tek boyutlu veya iki boyutlu olacaktır. Çünkü SIRALI fonksiyonu, kendi başına bir ardışık sayı dizisi oluşturmak için kullanılmaktadır. Genellikle, bu dizi doğrudan çalışma sayfasına dökülmektedir. Ayrıca, daha gelişmiş formüllerde sıkça karşılaşılan bir gereklilik olan başka bir formül içinde bir sayısal dizi oluşturmak için de kullanılmaktadır.

SIRALI fonksiyonu dört argüman alır: Bunlar; satırlar, sütunlar, başlangıç ve artış şeklindedir. Ayrıca, tüm değerler varsayılan olarak 1’dir. Satır ve sütun argümanları, çıktıda oluşturulacak satır ve sütun sayısını kontrol eder. Örneğin, aşağıdaki formüller satır ve sütunlarda 1 ile 5 arasındaki sayıları oluşturur:

=SIRALI(5; 1) // 5 satırda {1; 2; 3; 4; 5} döner
=SIRALI(1; 5) // 5 sütunda {1, 2, 3, 4, 5} döner

SIRALI fonksiyonunun çıktısının, bitişik hücrelere dökülen bir dizi değer olduğunu unutmayın. SIRALI fonksiyonunun söz dizimi satırların gerekli olduğunu belirtir, ancak satırlar veya sütunlar atlanabilir:

=SIRALI(5) // 5 satırda {1; 2; 3; 4; 5} döner
=SIRALI(; 5) // 5 sütunda {1, 2, 3, 4, 5} döner

Başlangıç argümanı, sayısal dizideki başlangıç noktasını belirtir ve artış her değer arasındaki artışı kontrol eder. Aşağıdaki formüllerin her ikisi de başlangıç değeri olarak 10 ve artış değeri olarak 5 kullanır:

=SIRALI(3; 1; 10; 5) // 3 satırda {10; 15; 20} döner
=SIRALI(1; 3; 10; 5) // 3 sütunda {10, 15, 20} döner

Örnekler

Aşağıdaki ekranda gösterilen örnekte, B4 hücresindeki formül şu şekildedir:

=SIRALI(10; 5; 0; 3)

Bu yapılandırma ile SIRALI, 10 satır ve 5 sütunluk bir dizi döndürür, sıfırdan başlar ve 3’er artar. Böylece, sonuç 0’dan başlayıp 147’ye kadar olan 50 sayı olacaktır.

Pozitif ve Negatif Değerler

Bu fonksiyon hem pozitif hem de negatif değerlerle çalışmaktadır. -10’dan başlayarak ve 2’şer artarak sıfıra kadar olan değerleri sıralamak için:

=SIRALI(6; 1; -10; 2) // {-10; -8; -6; -4; -2; 0} döner

10’dan sıfıra kadar olan değerleri sıralamak için:

=SIRALI(11; 1; 10; -1) // {10; 9; 8; 7; 6; 5; 4; 3; 2; 1; 0} döner

Tarih Dizisi Oluşturma

Excel’deki tarihler seri numaralarıdır. Böylece SIRALI fonksiyonu ile sıralı tarihleri kolayca oluşturulmaktadır. Örneğin, bugünden başlayarak 10 günlük bir liste oluşturmak için:

=SIRALI(1; 10; BUGÜN(); 1)

2022 yılının her ayının ilk gününe karşılık gelen 12 tarihi oluşturmak için:

=ETARİH(TARİH(2022; 1; 1); SIRALI(12; 1; 0))

Bu tarihleri ay isimlerine dönüştürmek için METNEÇEVİR fonksiyonunu kullanılmaktadır:

=METNEÇEVİR(ETARİH(TARİH(2022; 1; 1); SIRALI(12; 1; 0)); "aaaa")

SIRALI Fonksiyonu Sonuç

Excel’in SIRALI fonksiyonu, belirli bir sıraya göre dizi oluşturmak için kullanışlı bir araçtır. Bu yazıda, SIRALI fonksiyonunun ne olduğunu, nasıl kullanıldığını ve örneklerle açıklamalarını adım adım ele alınmaktadır. Artık, kendi veri setlerinizi SIRALI fonksiyonunu kullanarak kolayca düzenleyebilirsiniz. Böylece, verileri analiz etmekte oldukça kolay hale gelecektir.